Add support for creating Clojure namespaces.

Fixes #78

Author: ericdallo

CHANGELOG.md

@@ -2,6 +2,8 @@
 
 ## [Unreleased]
 
+- Add support for creating Clojure namespaces. #78
+
 ## 3.4.0
 
 - Fix go to declaration or usages. #70

src/main/clojure/com/github/clojure_lsp/intellij/extension/language_server_factory.clj

@@ -18,7 +18,7 @@
    [com.intellij.openapi.vfs LocalFileSystem VirtualFile]
    [com.redhat.devtools.lsp4ij LSPIJUtils LanguageServerFactory ServerStatus]
    [com.redhat.devtools.lsp4ij.client LanguageClientImpl]
-   [com.redhat.devtools.lsp4ij.client.features EditorBehaviorFeature LSPClientFeatures LSPProgressFeature]
+   [com.redhat.devtools.lsp4ij.client.features LSPClientFeatures LSPProgressFeature]
    [com.redhat.devtools.lsp4ij.installation LanguageServerInstallerBase]
    [com.redhat.devtools.lsp4ij.server OSProcessStreamConnectionProvider]
    [java.io File]

src/main/clojure/com/github/clojure_lsp/intellij/extension/new_file.clj

@@ -0,0 +1,63 @@
+(ns com.github.clojure-lsp.intellij.extension.new-file
+  (:require
+   [clojure.java.io :as io]
+   [clojure.string :as string]
+   [com.github.clojure-lsp.intellij.client :as lsp-client]
+   [com.rpl.proxy-plus :refer [proxy+]])
+  (:import
+   [com.github.clojure_lsp.intellij Icons]
+   [com.intellij.ide.actions CreateFileFromTemplateAction CreateFileFromTemplateDialog$Builder]
+   [com.intellij.ide.fileTemplates FileTemplate]
+   [com.intellij.psi PsiDirectory]))
+
+(set! *warn-on-reflection* true)
+
+(defn ^:private filename->source-path [filename project]
+  (let [source-paths (get-in (lsp-client/server-info project) [:final-settings "source-paths"])]
+    (first (filter #(string/starts-with? filename %) source-paths))))
+
+(defn ^:private dir->partial-namespace
+  [filename project]
+  (when-let [current-source-path (filename->source-path filename project)]
+    (some-> filename
+            (string/replace-first (re-pattern current-source-path) "")
+            (string/replace (System/getProperty "file.separator") ".")
+            (string/replace #"_" "-")
+            not-empty
+            (subs 1)
+            (str "."))))
+
+(defn ^:private dialog [project ^PsiDirectory dir ^CreateFileFromTemplateDialog$Builder builder]
+  (let [filename (.getPath (.getVirtualFile dir))
+        namespace (dir->partial-namespace filename project)]
+    (-> builder
+        (.setTitle "New Clojure namespace")
+        (.setDefaultText (or namespace ""))
+        (.addKind "Clojure (.clj)" Icons/CLOJURE "ClojureNamespace")
+        (.addKind "ClojureScript (.cljs)" Icons/CLOJURE_SCRIPT "ClojureScriptNamespace")
+        (.addKind "CLJC (.cljc)" Icons/CLOJURE "CLJCNamespace")
+        (.addKind "ClojureDart (.cljd)" Icons/CLOJURE_DART "ClojureDartNamespace"))))
+
+(defn ^:private create-file-from-template
+  [project ^String ns ^FileTemplate template ^PsiDirectory dir]
+  (let [dir-filename (.getPath (.getVirtualFile dir))
+        separator (System/getProperty "file.separator")
+        source-path (filename->source-path dir-filename project)
+        ns-path (-> ns
+                    (string/replace "." separator)
+                    (string/replace "-" "_"))
+        new-name (string/replace-first (.getCanonicalPath (io/file source-path ns-path))
+                                       (str dir-filename separator)
+                                       "")]
+    (CreateFileFromTemplateAction/createFileFromTemplate new-name template dir nil true)))
+
+(defn ->ClojureNewFileAction [project]
+  (proxy+
+   ["Clojure namespace" "Create a new Clojure namespace" Icons/CLOJURE]
+   CreateFileFromTemplateAction
+    (buildDialog [_ project dir builder]
+      (dialog project dir builder))
+    (getActionName [_ _dir new-name _template-name]
+      (str "Create Clojure namespace: " new-name))
+    (createFileFromTemplate [_ name template dir]
+      (create-file-from-template project name template dir))))

src/main/clojure/com/github/clojure_lsp/intellij/extension/register_actions_startup.clj

@@ -3,6 +3,7 @@
    [camel-snake-kebab.core :as csk]
    [com.github.clojure-lsp.intellij.client :as lsp-client]
    [com.github.clojure-lsp.intellij.editor :as editor]
+   [com.github.clojure-lsp.intellij.extension.new-file :as extension.new-file]
    [com.github.ericdallo.clj4intellij.action :as action]
    [com.github.ericdallo.clj4intellij.extension :refer [def-extension]]
    [com.github.ericdallo.clj4intellij.logger :as logger]
@@ -114,7 +115,15 @@
 
 (def-extension RegisterActionsStartup []
   ProjectActivity
-  (execute [_this ^Project _project ^CoroutineScope _]
+  (execute [_this ^Project project ^CoroutineScope _]
+    (action/register-action! :id "ClojureLSP.NewClojureFile"
+                             :title "Clojure namespace"
+                             :description "Create a Clojure namespace"
+                             :icon Icons/CLOJURE
+                             :action (extension.new-file/->ClojureNewFileAction project))
+    (action/register-group! :id "ClojureLSP.NewGroup"
+                            :children [{:type :add-to-group :group-id "NewGroup" :anchor :first}
+                                       {:type :reference :ref "ClojureLSP.NewClojureFile"}])
     (doseq [{:keys [name text description use-shortcut-of keyboard-shortcut]} clojure-lsp-commands]
       (action/register-action! :id (str "ClojureLSP." (csk/->PascalCase name))
                                :title text

src/main/resources/META-INF/plugin.xml

@@ -36,6 +36,10 @@
         <lang.syntaxHighlighterFactory language="clojure" implementationClass="com.github.clojure_lsp.intellij.extension.syntax_highlighter.ClojureSyntaxHighlighter"/>
         <colorSettingsPage implementation="com.github.clojure_lsp.intellij.extension.color_settings_page.ClojureColorSettingsPage"/>
 
+        <internalFileTemplate name="ClojureNamespace"/>
+        <internalFileTemplate name="ClojureScriptNamespace"/>
+        <internalFileTemplate name="CLJCNamespace"/>
+
         <!-- Features -->
         <postStartupActivity implementation="com.github.ericdallo.clj4intellij.extension.NREPLStartup"/>
         <postStartupActivity id="clojure-lsp-init-db" implementation="com.github.clojure_lsp.intellij.extension.init_db_startup.InitDBStartup"/>