Fix false positives by supporting __attribute__((noreturn)), format.

Use shared qll to avoid duplicating logic of detecting noreturn across both
specifiers and attributes, and to detect a possible returning stmt.

Author: MichaelRFairhurst

c/common/src/codingstandards/c/Noreturn.qll

@@ -0,0 +1,22 @@
+import cpp
+
+/**
+ * A function marked with _Noreturn or __attribute((noreturn))
+ */
+class NoreturnFunction extends Function {
+  NoreturnFunction() {
+    this.getASpecifier().getName() = "noreturn" or
+    this.getAnAttribute().getName() = "noreturn"
+  }
+}
+
+/**
+ * A function that may complete normally, and/or contains an explicit reachable
+ * return statement.
+ */
+predicate mayReturn(Function function) {
+  exists(ReturnStmt s |
+    function = s.getEnclosingFunction() and
+    s.getBasicBlock().isReachable()
+  )
+}

c/misra/src/rules/RULE-17-10/NonVoidReturnTypeOfNoreturnFunction.ql

@@ -12,12 +12,13 @@
 
 import cpp
 import codingstandards.c.misra
+import codingstandards.c.Noreturn
 
-from Function f, Type returnType
+from NoreturnFunction f, Type returnType
 where
   not isExcluded(f, NoReturnPackage::nonVoidReturnTypeOfNoreturnFunctionQuery()) and
-  f.getASpecifier().getName() = "noreturn" and
   returnType = f.getType() and
   not returnType instanceof VoidType
-select
-  f, "The function " + f.getName() + " is declared _noreturn but has a return type of " + returnType.toString() + "."
+select f,
+  "The function " + f.getName() + " is declared _noreturn but has a return type of " +
+    returnType.toString() + "."

c/misra/src/rules/RULE-17-11/FunctionWithNoReturningBranchShouldBeNoreturn.ql

@@ -11,14 +11,14 @@
 
 import cpp
 import codingstandards.c.misra
+import codingstandards.c.Noreturn
 
 from Function f
 where
   not isExcluded(f, NoReturnPackage::returnStatementInNoreturnFunctionQuery()) and
-  not f.getASpecifier().getName() = "noreturn" and
-  not exists(ReturnStmt s |
-    f = s.getEnclosingFunction() and
-    s.getBasicBlock().isReachable()
-  )
-select
-  f, "The function " + f.getName() + " cannot return and should be declared attribute _Noreturn."
+  not f instanceof NoreturnFunction and
+  not mayReturn(f) and
+  f.hasDefinition() and
+  f.getName() != "main" // Allowed exception; _Noreturn main() is undefined behavior.
+select f,
+  "The function " + f.getName() + " cannot return and should be declared attribute _Noreturn."

c/misra/src/rules/RULE-17-9/ReturnStatementInNoreturnFunction.ql

@@ -11,14 +11,10 @@
 
 import cpp
 import codingstandards.c.misra
+import codingstandards.c.Noreturn
 
-from Function f
+from NoreturnFunction f
 where
   not isExcluded(f, NoReturnPackage::returnStatementInNoreturnFunctionQuery()) and
-  f.getASpecifier().getName() = "noreturn" and
-  exists(ReturnStmt s |
-    f = s.getEnclosingFunction() and
-    s.getBasicBlock().isReachable()
-  )
-select
-  f, "The function " + f.getName() + " declared with attribute _Noreturn returns a value."
+  mayReturn(f)
+select f, "The function " + f.getName() + " declared with attribute _Noreturn returns a value."

c/misra/test/rules/RULE-17-10/NonVoidReturnTypeOfNoreturnFunction.expected

@@ -1 +1,4 @@
-No expected results have yet been specified
+| test.c:6:15:6:16 | f4 | The function f4 is declared _noreturn but has a return type of int. |
+| test.c:19:15:19:16 | f8 | The function f8 is declared _noreturn but has a return type of int. |
+| test.c:24:17:24:18 | f9 | The function f9 is declared _noreturn but has a return type of void *. |
+| test.c:26:31:26:33 | f10 | The function f10 is declared _noreturn but has a return type of int. |

c/misra/test/rules/RULE-17-10/test.c

@@ -1,9 +1,9 @@
 #include "stdlib.h"
 
-void f1(); // COMPLIANT
-int f2(); // COMPLIANT
+void f1();           // COMPLIANT
+int f2();            // COMPLIANT
 _Noreturn void f3(); // COMPLIANT
-_Noreturn int f4(); // NON-COMPLIANT
+_Noreturn int f4();  // NON-COMPLIANT
 
 void f5() { // COMPLIANT
 }
@@ -21,4 +21,6 @@ _Noreturn int f8() { // NON-COMPLIANT
   return 0;
 }
 
-_Noreturn void* f9(); // NON-COMPLIANT
+_Noreturn void *f9(); // NON-COMPLIANT
+
+__attribute__((noreturn)) int f10(); // NON-COMPLIANT

c/misra/test/rules/RULE-17-11/FunctionWithNoReturningBranchShouldBeNoreturn.expected

@@ -1,4 +1,4 @@
 | test.c:7:6:7:21 | test_noreturn_f2 | The function test_noreturn_f2 cannot return and should be declared attribute _Noreturn. |
-| test.c:19:6:19:21 | test_noreturn_f4 | The function test_noreturn_f4 cannot return and should be declared attribute _Noreturn. |
-| test.c:48:6:48:21 | test_noreturn_f8 | The function test_noreturn_f8 cannot return and should be declared attribute _Noreturn. |
-| test.c:64:6:64:22 | test_noreturn_f10 | The function test_noreturn_f10 cannot return and should be declared attribute _Noreturn. |
+| test.c:18:6:18:21 | test_noreturn_f4 | The function test_noreturn_f4 cannot return and should be declared attribute _Noreturn. |
+| test.c:47:6:47:21 | test_noreturn_f8 | The function test_noreturn_f8 cannot return and should be declared attribute _Noreturn. |
+| test.c:63:6:63:22 | test_noreturn_f10 | The function test_noreturn_f10 cannot return and should be declared attribute _Noreturn. |

c/misra/test/rules/RULE-17-11/test.c

@@ -8,7 +8,6 @@ void test_noreturn_f2(int i) { // NON_COMPLIANT
   abort();
 }
 
-
 _Noreturn void test_noreturn_f3(int i) { // COMPLIANT
   if (i > 0) {
     abort();
@@ -78,3 +77,15 @@ _Noreturn void test_noreturn_f11(int i) { // COMPLIANT
     i = 5;
   }
 }
+
+void test_noreturn_f12(); // COMPLIANT
+
+__attribute__((noreturn)) void test_noreturn_f13(int i) { // COMPLIANT
+  abort();
+}
+
+// Allowed by exception. It is undefined behavior for main() to be declared with
+// noreturn.
+int main(char **argv, int argc) { // COMPLIANT
+  abort();
+}

c/misra/test/rules/RULE-17-9/ReturnStatementInNoreturnFunction.expected

@@ -1,2 +1,3 @@
 | test.c:7:16:7:31 | test_noreturn_f2 | The function test_noreturn_f2 declared with attribute _Noreturn returns a value. |
 | test.c:32:16:32:31 | test_noreturn_f5 | The function test_noreturn_f5 declared with attribute _Noreturn returns a value. |
+| test.c:47:32:47:47 | test_noreturn_f7 | The function test_noreturn_f7 declared with attribute _Noreturn returns a value. |

c/misra/test/rules/RULE-17-9/test.c

@@ -43,3 +43,13 @@ _Noreturn void test_noreturn_f6(int i) { // COMPLIANT
     i = 5;
   }
 }
+
+__attribute__((noreturn)) void test_noreturn_f7(int i) { // NON_COMPLIANT
+  if (i > 0) {
+    abort();
+  }
+}
+
+__attribute__((noreturn)) void test_noreturn_f8(int i) { // COMPLIANT
+  abort();
+}