QL: add query detecting upper-case acronyms

Author: erik-krogh

ql/ql/src/codeql_ql/style/AcronymsShouldBeCamelCaseQuery.qll

@@ -0,0 +1,39 @@
+import ql
+
+/**
+ * Gets the name for a `node` that defines something in a QL program.
+ * E.g. a predicate, class, or module definition.
+ */
+string getName(AstNode node, string kind) {
+  result = node.(Class).getName() and kind = "class"
+  or
+  // not including CharPreds or db relations. The remaining are: classlessPredicate, classPredicate, newTypeBranch.
+  result = node.(ClasslessPredicate).getName() and
+  kind = "classlessPredicate"
+  or
+  result = node.(ClassPredicate).getName() and
+  kind = "classPredicate"
+  or
+  result = node.(NewTypeBranch).getName() and
+  kind = "newtypeBranch"
+  or
+  result = node.(VarDecl).getName() and
+  kind = "variable" and
+  not node = any(FieldDecl f).getVarDecl()
+  or
+  result = node.(FieldDecl).getName() and kind = "field"
+  or
+  result = node.(Module).getName() and kind = "module"
+}
+
+/**
+ * Holds if `name` seems to contain an upper-cased acronym that could be pascal-cased.
+ * `name` is the name of `node`, and `kind` describes what kind of definition `node` is.
+ */
+predicate shouldBePascalCased(string name, AstNode node, string kind) {
+  name = getName(node, kind) and
+  name.regexpMatch(".*[A-Z]{4,}.+") and
+  not node.hasAnnotation("deprecated") and
+  // allowed upper-case acronyms.
+  not name.regexpMatch(".*(PEP|AES|DES|EOF).*")
+}

ql/ql/src/queries/style/AcronymsShouldBeCamelCase.ql

@@ -0,0 +1,17 @@
+/**
+ * @name Acronyms should be PascalCase/camelCase.
+ * @description Acronyms should be PascalCase/camelCase instead of upper-casing all the letters.
+ * @kind problem
+ * @problem.severity warning
+ * @id ql/acronyms-should-be-pascal-case
+ * @tags correctness
+ *       maintainability
+ * @precision high
+ */
+
+import ql
+import codeql_ql.style.AcronymsShouldBeCamelCaseQuery
+
+from string name, AstNode node
+where shouldBePascalCased(name, node, _)
+select node, "Acronyms should be PascalCase/camelCase"