Window Function: frame exclude clause [CORE5338]

[firebird-automations]

Submitted by: @asfernandes

Jira_subtask_inward CORE1688

Votes: 3

frame clause is useful, especially for first_value,last_value, and nth_value| that consider only the
rows within the "window frame"

syntax :
<window frame clause> ::=
<window frame units> <window frame extent>
[ <window frame exclusion> ]

<window frame units> ::=
ROWS
| RANGE

<window frame extent> ::=
<window frame start>
| <window frame between>

<window frame start> ::=
UNBOUNDED PRECEDING
| <window frame preceding>
| CURRENT ROW

<window frame preceding> ::=
<unsigned value specification> PRECEDING

<window frame between> ::=
BETWEEN <window frame bound 1> AND <window frame bound 2>

<window frame bound 1> ::=
<window frame bound>

<window frame bound 2> ::=
<window frame bound>

<window frame bound> ::=
<window frame start>
| UNBOUNDED FOLLOWING
| <window frame following>

<window frame following> ::=
<unsigned value specification> FOLLOWING

<window frame exclusion> ::=
EXCLUDE CURRENT ROW
| EXCLUDE GROUP
| EXCLUDE TIES
| EXCLUDE NO OTHERS

[mrotteveel]

The currently implemented syntax in parse.y makes window_frame_exclusion_opt independent from the window_frame_extent, which is not correct according to the SQL:2016-2 syntax. The exclusion should only be specified when specifying a frame.