WiFi.status() == WL_CONNECTED although connection lost and WiFi.RSSI() == 0

[michael71]

I'm using the MKR1000 with the WiFi101 lib (and WiFiiUDP) to send Multicast UDP messages. (which works fine in principle).

But after some time (this can be after 30 min or after 2..4 hours), the UDP messages are no longer sent to the network.

When this happens, the WiFi.status() is still equal to WL_CONNECTED (!), but WiFi.RSSI() is equal to 0 (I'm using a Serial(USB) debug output). Calling WiFi.begin() and upd.beginMulti(..) again does not result in a new, working connection. (and it happens if I connect a Serial-USB connection or not). Power supply is either via PC/USB or with the 800mAh battery - this also makes no difference.

thx, michael.

P.S.
I uploaded a similar test SW to both the

• "samw25 xplained" board (using the "bare" ASF calls)
  and also to the
• "feather-m0-wifi-atwinc1500" (which does not have the SAMW25 hardware, but a similar SAMD21+WINC1500 combination) and this board also uses an Arduino lib derived from WiFi101)

and both these boards do not seem to have this problem.

P.S.2
My WiFi RSSIs are in the -55 to -40 range - the AP is in the same room with the boards.

[trlafleur]

This maybe related to what I see in issue: 80. Sometime I can run for a day or two, sometimes just for 10 minutes or less...

I'm testing with both the Feather M0 and MKR1000 board, same issue...

[sandeepmistry]

Closed via #85.

Please try out the master version the library.

[sandeepmistry]

Oops, closed the wrong issue, re-opening.

[sandeepmistry]

@michael71 could you please share an example sketch to reproduce the issue.

Also, it would be great if you could try out #77 (comment).

[michael71]

here is my example code: (I started 3 MKR1000s yesterday evening - 2 are still running after 32000 seconds, 1 has "rssi=0" since 2 hours ago)

/*****************************************************************
 RSSI_Test.ino
 version for MKR 1000
 *****************************************************************/
#include <SPI.h>
#include <WiFi101.h>
#include <WiFiUdp.h>

#define _DEBUG      // with Serial output

//************** network constants *****************************
WiFiUDP Udp;                           // using UDP messages
const IPAddress lanbahnip(239, 200, 201, 250);  // lanbahn multicast IP address
const unsigned int lanbahnport = 27027;      // lanbahn port to listen on

String ssid = "lonstoke";
String pass = "mypassword";

char packetBuffer[255]; //buffer to hold incoming packet
#define BUF_LEN   80
char buffer[BUF_LEN];       // for message strings

//******* timers *********************************************
long announceTimer;

void setup() {

#ifdef _DEBUG
    Serial.begin(57600); 
    long t1 = millis();
    while (!Serial)  {
        delay(100);
    }

    Serial.println("RSSI_Test");

#endif

    updateBuffer();
    announceTimer = millis(); // reset timer
    connectToWiFi();  
}

void connectToWiFi() {

#ifdef _DEBUG
    Serial.print("trying connect to ssid=");
    Serial.println(ssid);
#endif

    // attempt to connect to Wifi network:
    while (WiFi.status() != WL_CONNECTED)  {
        // Connect to WPA/WPA2 network:
        WiFi.begin(ssid, pass);
        delay(5000);  // wait

        Udp.beginMulti(lanbahnip, lanbahnport);
    // the issue happens with AND without "DEEP_AUTOMATIC"
        m2m_wifi_set_sleep_mode(M2M_PS_DEEP_AUTOMATIC, 1);

    }

    if (WiFi.status() == WL_CONNECTED) {
#ifdef _DEBUG
        Serial.print("successfully connected to ");
        Serial.println(ssid);
#endif
    }
}

void updateBuffer() {
    IPAddress ip = WiFi.localIP();
    int rssi = WiFi.RSSI();
    long secs = millis() / 1000;
    sprintf(buffer, "A RSSI_TEST_2 %d.%d.%d.%d %d %d", ip[0], ip[1], ip[2],
            ip[3], rssi, secs);
}

void readUdp() {
    if (WiFi.status() != WL_CONNECTED)
        return; // >>>>>>

    int packetSize = Udp.parsePacket();
    if (packetSize)  // read packet
    {
        // read the packet into packetBufffer
        int len = Udp.read(packetBuffer, 255);
        if (len > 0)
            packetBuffer[len] = 0;
    }
}

void sendAnnounceMessage() {
    if ((WiFi.status() == WL_CONNECTED) && (WiFi.RSSI() > -80)
            && (WiFi.RSSI() != 0)) {
        // wifi is o.k., we can send a message
        updateBuffer();
        // send lanbahn announce packet
        Udp.beginPacket(lanbahnip, lanbahnport);
        Udp.write(buffer);
        Udp.endPacket();

    } else {

#ifdef _DEBUG
        Serial.println("ERROR: wifi connection lost, rssi low or zero");
        Serial.print("status=");
        Serial.println(WiFi.status());
        Serial.print("rssi=");
        Serial.println(WiFi.RSSI());
#endif
    }
}

void loop() {

    readUdp();

    // send the announce string every 20sec
    if ((millis() - announceTimer) >= 20000) {
        announceTimer = millis();
        sendAnnounceMessage();
#ifdef _DEBUG
        Serial.println(buffer);
#endif
    }

}

[michael71]

I will now start a test with the "Wifi101-Socket-Buffer" lib.

[michael71]

sorry, hit the wrong button

[sandeepmistry]

@michael71 thanks. I don't see a loop function in the sketch you provided.

[michael71]

sorry, sandeepmistry, I added the loop() to the listing ...

[michael71]

I did some more long term experiments, with the #77 lib and with the standard WiFi101 library.

I experienced rssi=0 both with and without the "#77" patch - and with and without running the board from battery or from a 5V-USB power source. 1 board still runs o.k. after 194700 seconds - others stop sending multicast UDP messages to the network (with WiFi.status() = WL_CONNECTED and WiFi.rssi()=0 ) after only 14000 secs. (I also had "Serial" used and "Serial" not used - also made no difference)

So I cannot (with my 4 MKR1000s) conclude a root cause for this phenomenon. It happens with different (attached) hardware, with different power supplies and with different WiFi101 libs (see above).

However, reconnecting (I have a "config" mode in my full SW, with a "reconnect" command) seems to work, therefore I will call this "reconnect" function whenever RSSI is zero:

reconnect() {
  WiFi.begin(ssid, pass);
  wifiRetries++;
  delay(1000);  // wait 1 seconds
  Udp.beginMulti(lanbahnip, lanbahnport);
  m2m_wifi_set_sleep_mode(M2M_PS_DEEP_AUTOMATIC, 1);
  Serial.print("trying reconnect, millis=");
  Serial.println(millis());
  Serial.print("#retries=");
  Serial.println(wifiRetries);
  delay(2000);
}

(I also added a watchdog with 8secs, reset in my loop() function - but this doesn't seem to reset the processor - because the "loop()" just runs fine all the time.)

[sandeepmistry]

Thanks, I'll setup a similar test here to see if I can reproduce it. Just to confirm, I should be able to reproduce if I only setup 2 MKR1000's to broadcast?

For now, let's avoid using the m2m_wifi_set_sleep_mode(M2M_PS_DEEP_AUTOMATIC, 1); since there's no official API for it we haven't really tested deep sleep mode.